# SPDX-FileCopyrightText: 2026 ToServeTheKing <austin@thebennett.net>
# SPDX-License-Identifier: GPL-3.0-or-later

# Maintainer: Austin Bennett <austin at thebennett dot net>
pkgname=kareer
pkgver=0.1.3
pkgrel=1
pkgdesc="Job application tracker with a Sankey pipeline view and a scriptable CLI (Kirigami)"
arch=('x86_64')
url="https://github.com/toservetheking/Kareer"
license=('GPL-3.0-or-later')
depends=(
  hicolor-icon-theme
  kcolorscheme
  kconfig
  kcoreaddons
  kcrash
  ki18n
  kiconthemes
  kirigami
  kirigami-addons
  qqc2-desktop-style
  qt6-base
  qt6-declarative
)
makedepends=(
  cmake
  extra-cmake-modules
)
checkdepends=(appstream)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('7c30d4ebf2375d151e5132a57ce5b51ae7772d78a798ffa62a640114d8ff1486')

build() {
  cmake -B build -S "Kareer-$pkgver" \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_TESTING=ON
  cmake --build build
}

check() {
  QT_QPA_PLATFORM=offscreen ctest --test-dir build --output-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}